breed [ edges edge ]
breed [ nodes node ]

globals [
  time           ;; how many clock ticks have passed in the model
  color-mode     ;; 0 = normal, 1 = when heard, 2 = times heard
  clique         ;; how many patches have heard the rumor
]

nodes-own [
  times-heard    ;; tracks times the rumor has been heard
  first-heard    ;; clock tick when first heard the rumor
  just-heard?    ;; tracks whether rumor was heard this round -- resets each round
]

edges-own [
  times-heard    ;; tracks times the rumor has been heard
  first-heard    ;; clock tick when first heard the rumor
  just-heard?    ;; tracks whether rumor was heard this round -- resets each round
  rewired?
]

;;; setup procedures

to setup [seed-one?]
  ca
  set time 0
  set color-mode 0
  set clique 0
  set-default-shape nodes "circle"
  set-default-shape edges "line"

  cct-nodes num-people []
  setup-default-edges
  if (randomize-edges?)
    [ rewire-all ]
  ask turtles
    [ set first-heard -1
      set times-heard 0
      set just-heard? false
      recolor ]
  ifelse seed-one?
    [ seed-one ]
    [ seed-random ]

  __layout-circle (sort nodes) max-pxcor - 1
  if ( spring-layout? )
  [

    repeat 15 [
      __layout-spring nodes 0.2 9 1
      display  ;; so we get smooth animation
    ]
  ]


  update
  setup-plots
  do-plots
end

to seed-one
  ask one-of nodes
     [ hear-rumor ]
end

to seed-random
  ;; seed with random number of rumor sources governed by init-clique slider
  ask nodes with [times-heard = 0]
    [ if (random-float 10.0) < init-clique
        [ hear-rumor ] ]
  if (count nodes with [ just-heard? = true] = 0)
    [ ask one-of nodes [ hear-rumor ] ]
end

to go
  if not any? nodes with [times-heard = 0]
    [ stop ]
  set time (time + 1)
  ask nodes
    [ if times-heard > 0
        [ spread-rumor ] ]
  update
  do-plots
  wait .1
end

to spread-rumor  ;; node procedure
  let mylink one-of __my-edges
  ask mylink
  [
    set just-heard? true
    set just-heard?-of __other-end true
    set color red - 2
  ]
end

to hear-rumor  ;; turtle procedure
  if first-heard = -1
    [ set first-heard time
      set just-heard? true ]
  set times-heard times-heard + 1
  recolor
end

to update
  ask turtles with [just-heard?]
    [ set just-heard? false
      hear-rumor ]
  
end

;;; coloring procedures

to recolor  ;; turtle procedure
  ifelse color-mode = 0
    [ recolor-normal ]
    [ ifelse color-mode = 1
      [ recolor-by-when-heard ]
      [ recolor-by-times-heard ] ]
end

to recolor-normal  ;; turtle procedure
  ifelse first-heard >= 0
    [ set color red ]
    [ set color blue ]
end

to recolor-by-when-heard ;; turtle procedure
  ifelse first-heard = -1
    [ ifelse (breed = nodes)
        [ set color gray - 2 ]
        [ set color black ]
    ]
    [ ifelse (time = 0)
      [ set color yellow ]
      [ set color scale-color yellow first-heard ((max values-from nodes [first-heard]) + 1.0) 0]
    ]
end

to recolor-by-times-heard  ;; turtle procedure
  ifelse (breed = nodes and times-heard = 0 )
    [ set color gray - 2 ]
    [ set color scale-color green times-heard 0 ((max values-from nodes [times-heard] + 0)) ]
end

;;; plotting procedures

to setup-plots
  set-current-plot "Successive Differences"
  set-plot-y-range 0 (count nodes / 5)
end

to do-plots
  let new-clique count nodes with [times-heard > 0]
  set-current-plot "Rumor Spread"
  plot (new-clique / count nodes) * 100
  set-current-plot "Successive Ratios"
  ifelse clique = 0
    [ plot 1 ]
    [ plot new-clique / clique ]
  set-current-plot "Successive Differences"
  plot new-clique - clique
  set clique new-clique
end




;;;;;;;;;;;;;;;;;;;;;;;
;;; Edge Operations ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to setup-default-edges
  ;; iterate over the nodes
  let n 0
  while [n < num-people]
  [
    ;; make edges with the next two neighbors
    ;; this makes a lattice with average degree of 4
    ask turtle n
    [
      let k 1
      while [ k <= (num-friends / 2)]
      [
        __create-edge-with turtle ( (n + k) mod num-people)
        [ set color gray ]
        set k (k + 1)
      ]
    ]
    set n (n + 1)
  ]
end

;; taken and modified from Small Worlds example -- we want a small world network to start with.
to rewire-all
  ask edges [set rewired? false]
  ask edges with [not rewired?] [
    without-interruption [

    ;; whether to rewire it or not?
    if (random-float 1) < .20  ;; rewiring probability is fixed at 20%
    [
      ;; "a" remains the same
      let node1 __end1
      ;; if "a" is not connected to everybody
      if value-from node1 [count __edge-neighbors] < (num-people - 1)
      [
        ;; find a node distinct from node1 and not already a neighbor of node1
        let node2 one-of nodes with [ (self != node1) and (not value-from self [__edge-neighbor? node1]) ]
        ;; rewire the edge
        rewire node2
        
        
      ]
    ]
    ]
  ]
end

;; rewires the edge by changing b to newb
to rewire [new-b]
  ;; remove "a" from "b"'s neighbor list and vice versa
  let a __end1
  let b __end2
  ask a [ __create-edge-with new-b [ set color gray set rewired? true ] ]
  ask a [ __remove-edge-with b ]
end

; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Rumor Mill model.
; http://ccl.northwestern.edu/netlogo/models/RumorMill.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/RumorMill
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
160
10
494
365
40
40
4.0
1
10
1
1
1
0
0
0
1
-40
40
-40
40

CC-WINDOW
5
540
660
635
Command Center
0

BUTTON
15
50
136
83
setup-random
setup false
NIL
1
T
OBSERVER
T
NIL

PLOT
222
372
429
525
Successive Differences
time
difference
0.0
20.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -2674135 true

PLOT
444
372
650
526
Successive Ratios
time
ratio
0.0
20.0
0.0
2.0
true
false
PENS
"default" 1.0 0 -2674135 true

PLOT
9
372
208
525
Rumor Spread
time
percent
0.0
20.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -2674135 true

BUTTON
7
323
84
356
step
go
NIL
1
T
OBSERVER
T
NIL

SLIDER
5
144
149
177
init-clique
init-clique
0.0
10.0
0.3
0.1
1
NIL

BUTTON
15
16
136
49
setup-one
setup true
NIL
1
T
OBSERVER
T
NIL

BUTTON
85
323
154
356
go
go
T
1
T
OBSERVER
NIL
NIL

BUTTON
505
117
651
150
color: normal
set color-mode 0\nask turtles\n  [ recolor ]
NIL
1
T
OBSERVER
T
NIL

BUTTON
505
151
651
184
color: when heard
set color-mode 1\nask turtles\n  [ recolor ]
NIL
1
T
OBSERVER
T
NIL

BUTTON
505
185
651
218
color: times heard
set color-mode 2\nask turtles\n  [ recolor ]
NIL
1
T
OBSERVER
T
NIL

MONITOR
507
314
597
363
clique %
(clique / count nodes)\n  * 100
3
1

SLIDER
5
107
149
140
num-people
num-people
5
250
100
1
1
NIL

SWITCH
11
259
149
292
spring-layout?
spring-layout?
0
1
-1000

SWITCH
11
220
148
253
randomize-edges?
randomize-edges?
0
1
-1000

SLIDER
5
182
148
215
num-friends
num-friends
2
20
4
2
1
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This program models the spread of a rumor.  The rumor spreads when a person who knows the rumor tells someone they are connect to in their social network.

Each person is represented as a circle in the network, and the lines drawn between the circles represent social ties.  If there is a line between circle A and circle B, it means that A and B are good enough friends that they share gossip with each other.

At each time step, every person who knows the rumor randomly chooses a friend to tell the rumor to.  The simulation keeps track of who knows the rumor, how many people know the rumor, and how many "repeated tellings" of the rumor occur.  (Of course, in real life, people probably remember who they've told the rumor to, and don't tell the same person more than twice or so...)

HOW TO USE IT
-------------
RANDOMIZE-EDGES? is a switch that determines whether the social network is a completely symmetrical circle of people connect to the two nearest people on either side of them, or whether it has been randomized to be something close to a "small world network".  (Using the same algorithm used in the Small World Networks model, with rewiring probability 20%)

NUM-FRIENDS determines the initial number of friends each person has in the graph.  If RANDOMIZE-EDGES? is on, this will be the average number of friends each person has, otherwise this will be the exact number. (Warning:  If NUM-FRIENDS = 2, then disconnected networks often result.  The simulation will run indefinitely, since there is no way for the whole population to learn the rumor.)

SPRING-LAYOUT? is purely a display option.  Would you like the network drawn as a perfect circle, or would you like it spaced out some by using the "spring placement" algorithm for drawing graphs?

As with any rumor, it has to start somewhere, with one or more individuals.  There are three ways to control the start of the rumor:

1) Single source: Press the SETUP-ONE button. This starts the rumor at one random person in the social network.
2) Random sources: Press the SETUP-RANDOM button with the INIT-CLIQUE slider set greater than 0. This "seeds" the rumor randomly by having each person have a percentage chance of knowing thing rumor initially.  This percentage is set using the INIT-CLIQUE slider.

To run the model, you can either "step" through each time step using the STEP button or allow the model to simply run continuously using the GO button.  The model will stop when everyone in the population knows the rumor.

There are three plot windows associated with this rumor model.

RUMOR SPREAD - plots the percentage of people who know the rumor at each time step.
SUCCESSIVE DIFFERENCES - plots the number of new people who are hearing the rumor at each time step.
SUCCESSIVE RATIOS - at each time step, plots the ratio of people who just learned the rumor to people who already knew it.

The monitor CLIQUE% is the percentage of the people that have heard the rumor.

The three coloring buttons to the right of the view give you topographic maps of the screen.  The COLOR: WHEN HEARD button colors the network different shades of YELLOW according to the first time that location heard the rumor.  The COLOR: TIMES HEARD button colors the network different shades of GREEN according to the number of times that location has heard the rumor.


THINGS TO NOTICE
----------------
There is a significant difference in behavior of this model, depending on whether the RANDOMIZE-EDGES box is checked.  Which is the more accurate model of how rumors are spread?  Which spreads the rumor more quickly?  Why?

With the RANDOMIZE-EDGES box checked: 
An interesting thing to notice about the spread of the rumor is that the "speed" with which the rumor spreads slows down as more and more people know the rumor.  Why is that?  How is that related to the number of "repeated" or "wasted" tellings of the rumor?  How do the two "differences" plot windows help you to understand the dynamics of the rumor spread?

When you color the graph by the "number of times heard", remember that you are getting two different levels of information.  The color of the circles tells you how many times the given person has heard the rumor.  The color of the lines tells you how many times the rumor has passed between these two people.  Which are generally brighter, the circles or the lines?  Why?

Look at the colorings of "times heard" and "when heard".  There is a correlation between them.  How strong is it, and why does it exist?  Are the differences between the graphs attributably solely to chance, or are there contributing factors that make one circle more like to be bright green even if it isn't bright yellow?  What about when comparing lines, instead of circles?

THINGS TO TRY
-------------

Try varying the number of friends each person has.  How does this affect the speed of rumor dispersal?  How does it it affect the plots?

Try it with RANODOMIZE-EDGES off, 100 people, 4 friends per person.  Then try with 20 friends per person. Which produces graphs that are closer to those created when randomness is enabled?  Why?

Look at the original Rumor Mill model in the model library.  It uses spatial proximity to demonstrate the spread of rumors.  How is the behavior of this model the same as the original Rumor Mill model?  How is it different?  Can you explain the similarities?  Which approach (networks or spatial) do you think is a better one for modeling the spread of rumors?


EXTENDING THE MODEL
-------------------
Here are some suggestions for ways to extend the model.

- Try using a new algorithm to create the original graph layout, different from both the symmetrical one, and the "small world" one.  How do rumors spread if your graph is a tree (there is only one path of friendship between any two given people in the society)?  If it is a complete graph (every people is friends with every other people).

- Assign a probability with which the rumor is told.  In the current model, each time a person meets his/her neighbor, s/he tells the neighbor the rumor.  How would the spread of the rumor change if the telling of the rumor took place only 50% of the time? or 30% of the time?

- Add mouse support.  Make it so that you can use the mouse to choose precisely which people know the rumor initially.

- Try using a directed graph, instead of an undirected one.  i.e. Alice might tell rumors to Bobby, but Bobby doesn't pass rumors back to Alice -- he only passes them along to Cynthia.


NETLOGO FEATURES
----------------
This model makes use of the network primitives in NetLogo, to create non-spatial relationships between turtles.


RELATED MODELS
--------------
Virus, AIDS, Small World Networks


CREDITS AND REFERENCES
----------------------
This model is an extension of the Rumor Mill model from the model library in NetLogo.  Below are the credits and references for that model.

The Rumor Mill model is itself an extension of a physical experiment where spatial proximity was not a factor in the spread of the rumor.  Contact Helen M. Doerr at hmdoerr@syr.edu regarding papers in preparation.  Thanks to Dr. Doerr for inspiration for this model.

To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo Rumor Mill model. http://ccl.northwestern.edu/netlogo/models/RumorMill. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 1998 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/RumorMill for terms of use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.2
@#$#@#$#@
setup true
repeat 90 [ go ]
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@