globals [
  time           ;; how many clock ticks have passed in the model
  color-mode     ;; 0 = normal, 1 = when heard, 2 = times heard
  clique         ;; how many patches have heard the rumor
  
  ;; Modifications to make this an "Information Age" Rumor Mill
  rumor-target           ;; the patch that is the "target" of the rumor
  event-just-witnessed?  ;; needed for the "witnesses always talk" feature
  emails-sent            ;; the total number of emails sent
  new-emails-sent        ;; for plotting emails sent per period
]

patches-own [ 
  times-heard    ;; tracks times the rumor has been heard 
  first-heard    ;; clock tick when first heard the rumor 
  just-heard?    ;; tracks whether rumor was heard this round -- resets each round 
  
  ;; Modifications to make this an "Information Age" Rumor Mill
  heard-via      ;; how did we last hear the rumor? (word-of-mouth via email)
  times-emailed  ;; tracks how many times the rumor has been emailed
] 

;;; setup procedures

to setup [seed-one?]
  ca
  set time 0
  set color-mode 0
  set clique 0
  set emails-sent 0
  set new-emails-sent 0
  
  ;; Pick the "target" of the rumor
  set rumor-target (patch (screen-edge-x - (random (2 * screen-edge-x)))
                          (screen-edge-y - (random (2 * screen-edge-y))))

  ask patches 
    [ set first-heard -1
      set times-heard 0
      set times-emailed 0
      set just-heard? false
      recolor ]
  ifelse seed-one?
    [ seed-one ]
    [ seed-random ]
            
  ;; The embarassing event just occured
  if witnesses-always-talk?
    [ set event-just-witnessed? true  ]
  
  update
  do-plots
end

to seed-one
  ;; tell the center patch the rumor
  ask patch 0 0
    [ hear-rumor ]
end

to seed-random
  ;; seed with random number of rumor sources governed by init-clique slider 
  ask patches with [times-heard = 0]
    [ if (random 100.0) < init-clique
        [ hear-rumor ] ]
end

to go
  if not any patches with [times-heard = 0]
    [ stop ]
  set time (time + 1) 
  ask patches
    [ if times-heard > 0
        [ spread-rumor ] ]
  if event-just-witnessed?
    [ set event-just-witnessed? false ]
  update 
  do-plots
end

to spread-rumor  ;; patch procedure
  locals [neighbor max-care-distance people-to-email]
  
  set people-to-email []  ;; empty list (don't tell anybody)
  
  ;; Decide if the agent is going to tell anybody or if they are too
  ;; self-absorbed to bother talking about somebody else
  if event-just-witnessed? or ((random 100) > (self-centeredness * 100))
    [  
    
    ;; We'll just use a simple attenuation model because the previous attempt is
    ;; too slow to repeatedly calculate
    ifelse interest-attenuation > 0
      [ set max-care-distance ( (1 / interest-attenuation) ^ 2) ]
      [ set max-care-distance 999999 ]
      
    ;; Is the target of the rumor close enough to the agent in the 
    ;; "social scene" to bother telling anybody the rumor. In other
    ;; words, does he/she care?
    ;;
    ;; Make the attenuation "fuzzy" by making distant relations less likely
    ;; to be interested in repeating the rumor.
    if event-just-witnessed? or (((distance-nowrap rumor-target) < max-care-distance) and (random max-care-distance > (distance-nowrap rumor-target)))
      [
      
      ;; Pick a random neighbor to tell
      ifelse eight-mode?
        [ set neighbor random-one-of neighbors ]
        [ set neighbor random-one-of neighbors4 ]
      
      ;; Tell the neighbor
      if wrap? or not wrapped-neighbor? neighbor
        [ tell-rumor neighbor "word-of-mouth" ]
        
      ;; If the internet is up and running, decide whether to email the rumor
      ;; based on the "desire-to-email" slider
      if internet and (repeat-emails? or (times-emailed < 2 and just-heard?)) and ((random 100) < (desire-to-email * 100)) 
        [
          repeat random spam-capacity  ;; number of recipients depends on the "spam capacity" slider
            [ 
              set people-to-email lput (random-one-of patches) people-to-email   ; remember to tell the email recipient
              set new-emails-sent (new-emails-sent + 1)  ;; count how many emails have been sent in total
            ]
              
          ;; Remember that we've emailed people about this before    
          set times-emailed (times-emailed + 1)
        ]
        
      ] ;; end if (distance to rumor-target)
      
    ;; Tell the rumor to everybody we decided to tell
    if not empty? people-to-email 
      [ foreach people-to-email [ tell-rumor ? "email" ] ]
      
    ] ;; end if (self-centeredness)
end

to tell-rumor [person-to-tell method]
    set just-heard?-of person-to-tell true
    set heard-via-of person-to-tell method
end

;; the neighbors and neighbors4 primitives always wrap,
;; so if WRAP? is false we need to reject "neighbors" that
;; are only neighbors because of wrapping
to-report wrapped-neighbor? [neighbor]  ;; patch procedure
  report (abs (pxcor - pxcor-of neighbor) > 1) or
         (abs (pycor - pycor-of neighbor) > 1)
end

to hear-rumor  ;; patch procedure
  if first-heard = -1
    [ set first-heard time
      set just-heard? true ]
  set times-heard times-heard + 1
  recolor
end

to update 
  ask patches with [just-heard?]
    [ set just-heard? false
      hear-rumor ]
end

;;; coloring procedures

to recolor  ;; patch procedure
  ifelse color-mode = 0
    [ recolor-normal ]
    [ ifelse color-mode = 1
      [ recolor-by-when-heard ]
      [ recolor-by-times-heard ] ]
end

to recolor-normal  ;; patch procedure
  ifelse first-heard >= 0 
    [ 
      ifelse heard-via = "word-of-mouth"
        [ set pcolor red ]
        [ set pcolor orange ] 
    ]
    [ set pcolor blue ]

  ;; Color the target of the rumor green
  if (self = rumor-target)
    [ set pcolor green ]
end

to recolor-by-when-heard  ;; patch procedure
  ifelse first-heard = -1
    [ set pcolor black ]
    [ set pcolor scale-color yellow first-heard screen-size-x 0 ]
end

to recolor-by-times-heard   ;; patch procedure
  set pcolor scale-color green times-heard 0 screen-size-x
end

;;; mouse handling

to spread-rumor-with-mouse
  if mouse-down?
    [ ask patch-at mouse-xcor mouse-ycor
        [ hear-rumor ] ]
end

;;; plotting procedures

to setup-plots
  set-current-plot "Successive Differences"
  set-plot-y-range 0 (count patches / 5)
end

to do-plots
  locals [new-clique]
  set new-clique count patches with [times-heard > 0]

  ;; The "Rumor Spread" plot  
  set-current-plot "Rumor Spread" 
  plot (new-clique / count patches) * 100

;  set-current-plot "Successive Ratios"
;  ifelse clique = 0 
;    [ plot 1 ]
;    [ plot new-clique / clique ]

  ;; The "Successive Differences" plot
  set-current-plot "Successive Differences" 
  plot new-clique - clique
  set clique new-clique
  
  ;; The "Emails Sent" plot
  set-current-plot "Emails Sent"
  plot new-emails-sent - emails-sent
  set emails-sent new-emails-sent
  
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Rumor Mill model.
; http://ccl.northwestern.edu/netlogo/models/RumorMill.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
153
10
466
344
50
50
3.0
1
10
0
0

CC-WINDOW
470
102
834
207
Command Center

BUTTON
16
75
137
108
setup-random
setup false
NIL
1
T
OBSERVER

PLOT
237
386
497
565
Successive Differences
time
difference
0.0
20.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -65536 true

PLOT
501
386
717
565
Emails Sent
time
emails sent
0.0
20.0
0.0
2.0
true
false
PENS
"default" 1.0 0 -65536 true

PLOT
8
386
231
565
Rumor Spread
time
percent
0.0
20.0
0.0
100.0
true
false
PENS
"default" 1.0 0 -65536 true

BUTTON
2
222
79
255
step
go
NIL
1
T
OBSERVER

SLIDER
2
114
150
147
init-clique
init-clique
0.0
10.0
0.1
0.1
1
NIL

SWITCH
2
182
149
215
eight-mode?
eight-mode?
0
1
-1000

SWITCH
2
148
149
181
wrap?
wrap?
1
1
-1000

BUTTON
16
41
137
74
setup-one
setup true
NIL
1
T
OBSERVER

BUTTON
80
222
149
255
go
go
T
1
T
OBSERVER

BUTTON
192
350
338
383
color: normal
set color-mode 0\nask patches\n  [ recolor ]
NIL
1
T
OBSERVER

BUTTON
341
350
487
383
color: when heard
set color-mode 1\nask patches\n  [ recolor ]
NIL
1
T
OBSERVER

BUTTON
490
350
636
383
color: times heard
set color-mode 2\nask patches\n  [ recolor ]
NIL
1
T
OBSERVER

MONITOR
23
271
113
320
clique %
(clique / count patches)\n  * 100
3
1

BUTTON
8
350
189
383
NIL
spread-rumor-with-mouse
T
1
T
OBSERVER

SLIDER
661
10
833
43
self-centeredness
self-centeredness
0
1
0.57
0.01
1
NIL

SLIDER
469
46
641
79
interest-attenuation
interest-attenuation
0
1
0.0
0.01
1
NIL

SWITCH
469
225
572
258
internet
internet
0
1
-1000

SLIDER
469
261
641
294
desire-to-email
desire-to-email
0
1
0.33
0.01
1
NIL

SLIDER
644
261
816
294
spam-capacity
spam-capacity
1
25
6
1
1
NIL

SWITCH
469
298
610
331
repeat-emails?
repeat-emails?
1
1
-1000

SWITCH
469
10
658
43
witnesses-always-talk?
witnesses-always-talk?
0
1
-1000

@#$#@#$#@
WHAT IS IT?
-----------
This program models the spread of a rumor about a specific person in the population (the "target" of the rumor). The rumor is spread in an Information Age environment, where email is available to all members of the population. The rumor can spread in two ways: a person who knows the rumor can tell one of their neighbors, or they can email the rumor to one or more friends. The less interested a person is in the the target of the rumor, the less likely they are to share the rumor with others. Spacial proximity is used to determine how interested the person is. In other words, the closer a person is to the target of the rumor, the more interested they are and thus the more likely they are to share the rumor.

The neighbors can be defined as either the four adjacent people or the eight adjacent people. At each time step, every person who knows the rumor decides whether they are interested enough to share it. If so, they randomly choose a neighbor to tell the rumor to. They may also choose to email the rumor to a random number of friends. The simulation keeps track of who knows the rumor, how many people know the rumor, and how many "repeated tellings" of the rumor occur. It also keeps track of how many emails have been sent.


HOW TO USE IT
-------------
WRAP? is a switch which when set on allows the rumor to wrap top and bottom and left and right, as if the grid were on a torus. When set off, the rumor spreads as if the grid is bounded, without wrapping.

EIGHT-MODE? is a switch that determines whether at each time step the rumor spreads to one of four randomly chosen neighbors, or one of eight such neighbors.

WITNESSES-ALWAYS-TALK? is a switch that determines whether the rumor seeds (the "witnesses") will always decide to share the rumor, no matter how interested they are. This only applies to the members of the clique who join during setup.

SELF-CENTEREDNESS is a slider that determines how self-involved members of the population are. The more self-involved they are, the less likely they are to spread rumors about others (they are too busy talking about themselves).

INTEREST-ATTENUATION is a slider that determines how distance from the target of the rumor affects a person's interest in the rumor. The higher attenuation is, the more quickly interest drops off as distance increases.

INTERNET is a switch that determines whether the internet (and email) is available for sharing rumors. Turning off this switch reverts the model from an Information Age model to a more traditional Rumor Mill model.

DESIRE-TO-EMAIL is a slider that determines how likely a person is to email a rumor that they are interested in. The higher the value, the more likely the person is to email.

SPAM-CAPACITY is a slider that determines how many emails a person is capable of sending out at a time. The sender will send a random number of emails between zero and spam-capacity when sending email.

REPEAT-EMAILS? is a switch that determines whether people will send out batches of email containing a rumor more than once. When off, for example, Joe may send an email to four of his friends upon hearing the rumor, but next time he hears the rumor he will refrain from emailing.

As with any rumor, it has to start somewhere, with one or more individuals. These can be thought of the "witnesses." There are three ways to control the start of the rumor:

1) Single source: Press the SETUP-ONE button. This seeds the initial witness at one point in the center of the screen and chooses a randomly-located target.
2) Random source: Press the SETUP-RANDOM button with the INIT-CLIQUE slider set greater than 0. This "seeds" the witnesses randomly by choosing a percentage of the population that knows the rumor initially.  This percentage is set using the INIT-CLIQUE slider. The target of the rumor is picked randomly.
3) Choose source with mouse: Press either SETUP-ONE or SETUP-RANDOM, then press the SPREAD-RUMOR-WITH-MOUSE button.  While this button is down, clicking the mouse button on a patch in the graphics window will tell the rumor to that patch.  

To run the model, you can either "step" through each time step using the STEP button or allow the model to simply run continuously using the GO button.  The model will stop when everyone in the population knows the rumor.

There are three plot windows associated with this rumor model. 

RUMOR SPREAD - plots the percentage of people who know the rumor at each time step.
SUCCESSIVE DIFFERENCES - plots the number of new people who are hearing the rumor at each time step.
EMAILS SENT - plots the number of emails that are sent in any given period

The monitor CLIQUE% is the percentage of the patches that have heard the rumor.

The three coloring buttons to the right of the graphics window give you topographic maps of the screen. 

The COLOR: NORMAL button colors the screen green for the target of the rumor, red for people who have heard the rumor via word-of-mouth, orange for people who have heard the rumor via email, and blue for people who do not yet know the rumor. 

The COLOR: WHEN HEARD button colors the screen different shades of YELLOW according to the first time that location heard the rumor.  

The COLOR: TIMES HEARD button colors the screen different shades of GREEN according to the number of times that location has heard the rumor.


THINGS TO NOTICE
----------------

It is interesting to note that the speed of the rumor's spread can be heavily dependent on whether those who know the rumor are interested in the rumor's target. A slowly-spreading rumor can explode if emailed to a particularly interested party. Experiment with interest-attenuation to see how this affects the spread. As with the traditional Rumor Mill model, the rumor spread slows down once a critical mass of very interested parties know the rumor. 

It can be interesting to compare the manner in which rumors spread with the internet available versus when it is not available. Desire-to-email and spam-capacity significantly affect the spread of the rumor in the Information Age, as does the interest-attenuation. 


THINGS TO TRY
-------------

Adjust INTEREST-ATTENUATION to get more or less people interested in spreading the rumor. How does a high attenuation affect the likelihood of a rumor spreading wildly via the internet?

Explore how changing peoples' ability to communicate with large number of people via the internet affects the speed of the rumor's spread. Why is a rumor more likely to take root when people have a higher email capacity?


EXTENDING THE MODEL
-------------------
Here are some suggestions for ways to extend the model.

- Introduce a model of rumor accuracy. As the rumor takes more "jumps", the rumor's accuracy may decrease. How accurate is the version of the rumor that outlying members of the clique hear?

- Change the model for interest-attenuation. How would a more complex model of a person's interest in the rumor affect its spread?

- Introduce physical barriers into the simulation.  These spatial barriers would be obstacles around which the rumor would have to spread.  One could imagine a room where there was only a one cell entry.  How long would it take to reach the entire population in this case?  And how would that curve (the function of the number of people who know the rumor versus time) compare to the spread of the rumor when there was no such barrier? How would the presence of the internet affect such a model?


NETLOGO FEATURES
----------------
Note the use of the "neighbors" and "neighbors4" primitives to implement 8-mode and 4-mode, respectively.


RELATED MODELS
--------------
Virus, AIDS


CREDITS AND REFERENCES
----------------------
Modified by Greg Dunham Oct 9, 2003 from the original Rumor Mill model by Uri Wilensky (see below for full reference).

This model is itself an extension of a physical experiment where spatial proximity was not a factor in the spread of the rumor.  Contact Helen M. Doerr at hmdoerr@syr.edu regarding papers in preparation.  Thanks to Dr. Doerr for inspiration for this model.

To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo Rumor Mill model. http://ccl.northwestern.edu/netlogo/models/RumorMill. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 300 300 150 195 150 195 7 105 7 105 150 105 150 0 150

bee
true
0
Polygon -256 true false 151 152 137 77 105 67 89 67 66 74 48 85 36 100 24 116 14 134 0 151 15 167 22 182 40 206 58 220 82 226 105 226 134 222
Polygon -16777216 true false 151 150 149 128 149 114 155 98 178 80 197 80 217 81 233 95 242 117 246 141 247 151 245 177 234 195 218 207 206 211 184 211 161 204 151 189 148 171
Polygon -7566196 true true 246 151 241 119 240 96 250 81 261 78 275 87 282 103 277 115 287 121 299 150 286 180 277 189 283 197 281 210 270 222 256 222 243 212 242 192
Polygon -16777216 true false 115 70 129 74 128 223 114 224
Polygon -16777216 true false 89 67 74 71 74 224 89 225 89 67
Polygon -16777216 true false 43 91 31 106 31 195 45 211
Line -1 false 200 144 213 70
Line -1 false 213 70 213 45
Line -1 false 214 45 203 26
Line -1 false 204 26 185 22
Line -1 false 185 22 170 25
Line -1 false 169 26 159 37
Line -1 false 159 37 156 55
Line -1 false 157 55 199 143
Line -1 false 200 141 162 227
Line -1 false 162 227 163 241
Line -1 false 163 241 171 249
Line -1 false 171 249 190 254
Line -1 false 192 253 203 248
Line -1 false 205 249 218 235
Line -1 false 218 235 200 144

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 34 34 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

spacecraft
true
0
Polygon -7566196 true true 150 300 120 165 45 45 75 60 150 120 225 60 255 45 180 165

thin-arrow
true
0
Polygon -7566196 true true 150 300 300 150 180 150 180 4 120 4 120 150 120 150 0 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 1.3.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@