;; edges and nodes are both turtles
breeds [edges nodes]

;;;;;;;;;;;;;;;
;; Variables ;;
;;;;;;;;;;;;;;;

nodes-own
[
  node-clustering-coefficient ;; clustering coefficient of the node
  distance-from-other-nodes   ;; list of distances of this node from other nodes
  has-change?
]

;; rewired? keeps track of whether the edge has been rewired or not
edges-own [rewired?]

globals
[
  clustering-coefficient               ;; the clustering coefficient of the network
                                       ;; this is the average of clustering coefficients of all nodes
  average-path-length                  ;; average path length of the network
  clustering-coefficient-of-lattice    ;; the clustering coefficient of the initial lattice
  average-path-length-of-lattice       ;; average path length of the initial lattice
  infinity                             ;; a very large number.
                                         ;; used to denote distance between two nodes which
                                         ;; don't have a connected or unconnected path between them
  highlight-string                     ;; message that appears on the node properties monitor
  nbr-rewired                          ;; counter for number of edges that get rewired.  used for plots.
  time
]

;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to setup
  ca
  set infinity 99999 ;; just an arbitary choice for a large number
  set-default-shape nodes "circle"
  set-default-shape edges "line"
  make-nodes
  ;; we need to find initial values for lattice
  wire-them
  ;;calulate average path length and clustering coefficient for the lattice
  do-calculations
  ;; setting the values for the initial lattice
  set clustering-coefficient-of-lattice clustering-coefficient
  set average-path-length-of-lattice average-path-length
  set nbr-rewired 0
  set highlight-string ""
  set time 0
  
  rewire-all
  layout
  
  ask turtle random num-nodes
  [ set has-change? true
    set color red + 2
  ]
end

to spread-once
  if( any? nodes with [has-change? = false ] )
  [
    set time time + 1
    ask nodes with [ has-change? = true ]
    [
      ask __edges-neighbors
      [
        if( random-float 1 <= ( (node-clustering-coefficient-of myself + .1) / 
            ((node-clustering-coefficient-of myself + .1) + (node-clustering-coefficient-of self + .1)) ) )
        [
          set has-change? true
          set color red + 2
        ]
      ]
    ]
  ]
end

to spread-change
  while [ any? nodes with [has-change? = false ]]
  [
    set time time + 1
    ask nodes with [ has-change? = true ]
    [
      ask __edges-neighbors
      [
        if( random-float 1 <= ( (node-clustering-coefficient-of myself + .1) / 
            ((node-clustering-coefficient-of myself + .1) + (node-clustering-coefficient-of self + .1)) ) )
        [
          set has-change? true
          set color red + 2
        ]
      ]
    ]
  ]  
end

to make-nodes
  create-custom-nodes num-nodes
  [
    set color (gray + 2)
    set has-change? false
  ]
  ;; they will form a circle
  __layout-circle nodes screen-edge-x - 1
end

;;;;;;;;;;;;;;;;;;;;;;;
;;; Main Procedure ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to rewire-all
  ;; kill the old lattice, reset neighbors, and create new lattice
  ask edges  [die]
  wire-them
  set nbr-rewired 0
  ask edges [set rewired? false]
  ask edges with [not rewired?] [
    without-interruption [

    ;; whether to rewire it or not?
    if (random-float 1) < rewiring-probability
    [
      ;; "a" remains the same
      let node1 __src-end
      ;; if "a" is not connected to everybody
      if value-from node1 [count __edges-neighbors] < (num-nodes - 1)
      [
        ;; find a node distinct from node1 and not already a neighbor of node1
        let node2 random-one-of nodes with[ (self != node1) and (not value-from self [__edges-neighbor? node1]) ]
        set nbr-rewired nbr-rewired + 1  ;; counter for number of rewirings
        ;; rewire the edge
        rewire node2
      ]
    ]
    ]
  ]

  ;;calulate average path length and clustering coefficient for the network and plot
  do-calculations
end

to do-calculations
  ;; find the path lengths in the network
  find-path-lengths
  ;; check whether network got disconnected and ignore those runs (should not happen often);
  ;; we only want to calculate average path length when we have one connected component
  if (sum values-from nodes [length remove infinity distance-from-other-nodes] ) != (num-nodes * num-nodes )
  [
    show "network got disconnected"
    stop
  ]
  set average-path-length (sum values-from nodes [sum remove infinity distance-from-other-nodes])
                          / (sum values-from nodes [length remove infinity distance-from-other-nodes] )
  ;; find the clustering coefficient and add to the aggregate for all iterations
  find-clustering-coefficient
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Clustering computations ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to find-clustering-coefficient
  ifelse count nodes with [count __edges-neighbors > 1] = 0
  [
    ;; it is undefined
    ;; what should be this?
    set clustering-coefficient 0
  ]
  [
    let total 0
    ask nodes with [count __edges-neighbors <= 1]
    [set node-clustering-coefficient "undefined"]
    ask nodes with [count __edges-neighbors > 1]
    [
      let node self
      set node-clustering-coefficient (2 * count edges with [value-from __src-end [__edges-neighbor? node]
                                                         and value-from __dest-end [__edges-neighbor? node]]
                                             /( (count __edges-neighbors) * (count __edges-neighbors - 1) ) )
      ;; find the sum for the value at nodes
      set total total + node-clustering-coefficient
    ]
    ;; take the average
    set clustering-coefficient total / count nodes with [count __edges-neighbors > 1]
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Path length computations ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; Implements the Floyd Warshall algorithm for All Pairs Shortest Paths
;; It is a dynamic programming algorithm which builds bigger solutions
;; from the solutions of smaller subproblems using memoization that
;; is storing the results.
;; It keeps finding incrementally if there is shorter path through
;; the kth node.
;; Since it iterates over all nodes through k,
;; so at the end we get the shortest possible path for each i and j.
to find-path-lengths
  ;; reset the distance list
  ask nodes
  [
    set distance-from-other-nodes []
  ]

  let i 0
  let j 0
  let k 0
  let node1 random-one-of nodes
  let node2 random-one-of nodes
  ;; initialize the distance lists
  while [i < num-nodes]
  [
    set j 0
    while [j < num-nodes]
    [
      set node1 turtle i
      set node2 turtle j
      ;; zero from a node to itself
      ifelse i = j
      [
        set distance-from-other-nodes-of node1 lput 0 distance-from-other-nodes-of node1
      ]
      [
        ;; 1 from a node to it's neighbor
        ifelse value-from node1 [__edges-neighbor? node2]
        [
          set distance-from-other-nodes-of node1 lput 1 distance-from-other-nodes-of node1
        ]
        ;; infinite to everyone else
        [
          set distance-from-other-nodes-of node1 lput infinity distance-from-other-nodes-of node1
        ]
      ]
      set j j + 1
    ]
    set i i + 1
  ]
  set i 0
  set j 0
  let dummy 0
  while [k < num-nodes]
  [
    set i 0
    while [i < num-nodes]
    [
      set j 0
      while [j < num-nodes]
      [
        ;; alternate path length through kth node
        set dummy ( (item k distance-from-other-nodes-of turtle i) + (item j distance-from-other-nodes-of turtle k))
        ;; is the alternate path shorter?
        if dummy < (item j distance-from-other-nodes-of turtle i)
        [
          set distance-from-other-nodes-of turtle i replace-item j distance-from-other-nodes-of turtle i dummy
        ]
        set j j + 1
      ]
      set i i + 1
    ]
    set k k + 1
  ]

end

;;;;;;;;;;;;;;;;;;;;;;;
;;; Edge Operations ;;;
;;;;;;;;;;;;;;;;;;;;;;;

;; creates a new lattice
to wire-them
  ;; iterate over the nodes
  let n 0
  while [n < num-nodes]
  [
    ;; make edges with the next two neighbors
    ;; this makes a lattice with average degree of 4
    ask turtle n
    [
      __create-edges-with turtle ( (n + 1) mod num-nodes)
      [
        set rewired? false
        set color gray
      ]
      __create-edges-with turtle ( (n + 2) mod num-nodes)
      [
        set rewired? false
        set color gray
      ]
    ]
    set n (n + 1)
  ]
end

;; rewires the edge by changing b to newb
to rewire [newb]
  let node1 __src-end
  ask node1
  [
    __create-edges-with newb
    [
      set color cyan
      set rewired? true
    ]
  ]
  display ;; update display
  die
end


;;;;;;;;;;;;;;;;
;;; Graphics ;;;
;;;;;;;;;;;;;;;;

to highlight
  ;; reset changes done by previous highlight
  ask nodes [
              ifelse( has-change? = true )
              [set color red + 2]
              [set color gray + 2]]
  ask edges [set color (gray + 2)]
  if mouse-inside?
  [
    ;; getting the node closest to the mouse
    let min-d min values-from nodes [distancexy mouse-xcor mouse-ycor]
    let node random-one-of nodes with [ count __edges-neighbors > 0 and distancexy mouse-xcor mouse-ycor = min-d]
    ;; dont want to do recursion, just stopping it
    ifelse node = nobody
    [
      display
      highlight
    ]
    [
      ;; highlight the chosen node
      ask node
      [
        ifelse( has-change? = true )
        [set color pink - 1]
        [set color sky - 1]
        let pairs (length remove infinity distance-from-other-nodes)
        let local-val (sum remove infinity distance-from-other-nodes) / pairs
        ;; show node's clustering coefficient
        set highlight-string "Clustering Coefficient = " + precision node-clustering-coefficient 3 +
                               " and Avg Path Length = " + precision local-val 3 + " (for " + pairs + " nodes )"
      ]
      ;; highlight neighbors
      ask node
      [
        ask __edges-neighbors
        [
          ifelse( has-change? = true )
          [set color red - 1]
          [set color blue - 1]
          let other self
          ;; highligh edges connecting the chosen node to it's neighbors
          ask __all-edges
          [set color blue - 1]
        ]
      ]
      ;; highlight edges connecting the neighbors of the chosen node
      ;; the number of these edges(along with the number of neighbors)
      ;; is what determines the clustering coefficient
      ask edges
      [
        let src __src-end
        let dest __dest-end
        if value-from node [__edges-neighbor? src and __edges-neighbor? dest]
        [set color yellow]
      ]
    ]
  ]
end

to layout
  if not layout? [ stop ]
  ;; the number 10 here is arbitrary; more repetitions slows down the
  ;; model, but too few gives poor layouts
  repeat 10 [
    __layout-spring nodes 0.2 9 1
    display  ;; so we get smooth animation
  ]
end

; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) -- grant numbers
; REC #9814682 and REC-0126227.
;
; Copyright 2005 by Uri Wilensky.  Updated 2005.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2005).  NetLogo Small Worlds model.
; http://ccl.northwestern.edu/netlogo/models/SmallWorlds.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2005 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/SmallWorlds
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
495
10
925
461
17
17
12.0
1
10
1
1
1
0
1
1
1

CC-WINDOW
5
527
934
622
Command Center
0

BUTTON
15
19
86
52
NIL
setup\n
NIL
1
T
OBSERVER
T
NIL

SLIDER
13
70
185
103
num-nodes
num-nodes
5
150
60
1
1
NIL

SLIDER
206
70
477
103
rewiring-probability
rewiring-probability
0
1
0.5
0.01
1
NIL

MONITOR
495
464
925
513
Node Properties
highlight-string
3
1

BUTTON
333
19
477
52
NIL
highlight
T
1
T
OBSERVER
T
NIL

MONITOR
81
116
209
165
NIL
clustering-coefficient
3
1

MONITOR
219
116
347
165
NIL
average-path-length
3
1

SWITCH
364
124
467
157
layout?
layout?
0
1
-1000

BUTTON
99
19
206
52
spread change
spread-change
NIL
1
T
OBSERVER
T
NIL

MONITOR
14
115
71
164
time
time
0
1

BUTTON
220
19
303
52
spread once
spread-once
NIL
1
T
OBSERVER
T
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This model explores the spread of language variant change throughout a network consisting of 'weak' and 'strong' ties between language community members.  (Milroy 2002) proposes that the proportion of 'weak' neighborhood network ties determines the speed with which change propagates through a community.  The strength of a network tie is defined by its multiplexity and 'centrality' to a local community.  Looking at Belfast working-class neighborhoods, Milroy demonstrated that those speakers with the strongest vernacular (most 'exemplary' of a dialect) were generally those with the strongest network ties.  Her hypotheses are:

1. looseknit uniplex networks are susceptible to change.
2. weak ties provide bridges through which information and influence are propagated.

This predicts cascade diffusion through multiple weak ties.  When discussing the plausibility of a weak tie theory, Milroy use the following behavior to found its reasoning:

1. People central to a close-knit, norm enforcing group are likely to find innovation socially risky, but the adoption of an innovation already on the periphery of the group less so.
2. Socially mobile individuals are forced to deal with out-of-network people regularly, and accomodate to new language variants more freely.

To create a model that has a variable number of weak/strong ties, the "small world" simulation was ideal.


HOW IT WORKS
------------
This model is an adaptation of a model proposed by Duncan Watts and Steve Strogatz (1998). SETUP creates a connected network of NUM-NODES nodes with a variable amount of 'clustering,' or close-knit groups that include members who share friends.  The higher the REWIRING-PROBABILITY, the greater the number of nodes existing in close-knit groups.

During SETUP, a node is chosen at random to develop a new language variant of the community's dialect.  SPREAD CHANGE will spread this change throughout the entire network.  SPREAD ONCE will allow any people speaking the new variant to effect change in any to which they are tied.  The CLUSTERING COEFFICIENT is a measure of the proportion of weak/strong ties in the network.  A low clustering coefficient is indicative of a network comprised of numerous weak ties.
  
Average Path Length: Average path length is calculated by finding the shortest path between all pairs of nodes, adding them up, and then dividing by the total number of pairs. This shows us, on average, the number of steps it takes to get from one member of the network to another.

Clustering Coefficient:  Another property of small world networks is that from one person's perspective it seems unlikely that they could be only a few steps away from anybody else in the world.  This is because their friends more or less know all the same people they do. The clustering coefficient is a measure of this "all-my-friends-know-each-other" property.  More precisely, the clustering coefficient of a node is the ratio of existing links connecting a node's neighbors to each other to the maximum possible number of such links. The clustering coefficient for the entire network is the average of the clustering coefficients of all the nodes. A high clustering coefficient for a network is another indication of a small world.



HOW TO USE IT
-------------
The NUM-NODES slider controls the size of the network.  The REWIRING-PROBABILITY determines the fraction of nodes rewired from their original neighbors.  Choose a size and press SETUP.

When you press HIGHLIGHT and click on a node in the graphics window it color-codes the nodes and edges.  The node itself turns pink. Its neighbors and the edges connecting the node to those neighbors turn blue. Edges connecting the neighbors of the node to each other turn yellow. The amount of yellow between neighbors can gives you an indication of the clustering coefficient for that node.  The NODE-PROPERTIES monitor displays the average path length and clustering coefficient of the highlighted node only.  The AVERAGE-PATH-LENGTH and CLUSTERING-COEFFICIENT monitors display the values for the entire network.

If a "network is disconnected" message appears in the command center, that means that the network got fragmented into two pieces and the network properties were not plotted during that round.  We do not want to calculate and plot the average path length when the network is not one component.


THINGS TO NOTICE
----------------

As the clustering coefficient lowers, the time it takes for a variant to saturate the community drops (more weak ties means faster change).  

Note that for certain values of the rewiring probability, the average path length decreases faster than the clustering coefficient.  In fact, there is a range of values for which the average path length is much smaller than the clustering coefficient.  Networks in that range are considered small worlds.



NETLOGO FEATURES
----------------
Both nodes and edges are turtles.  Edge turtles have the "line" shape.  The edge turtle's SIZE variable is used to make the edge be the right length.

Lists are used heavily in this model.  Each node maintains a list of its neighboring nodes.  Lists are also used in the procedure that calculates shortest paths and to find the clustering coefficient of a node.


RELATED MODELS
--------------
See other models in the Networks section of the Models Library, such as Giant Component and Preferential Attachment.


CREDITS AND REFERENCES
----------------------
This model is adapted from:
Wilensky, U. (2005).  NetLogo Small Worlds Model.
Duncan J. Watts, Six Degrees: The Science of a Connected Age (W.W. Norton & Company, New York, 2003), pages 83-100.

The work described here was originally published in:
DJ Watts and SH Strogatz. Collective dynamics of 'small-world' networks, Nature,
393:440-442 (1998)

The small worlds idea was first made popular by Stanley Milgram's famous experiment (1967) which found that two random US citizens where on average connected by six acquaintances (giving rise to the popular "six degrees of separation" expression):
Stanley Milgram.  The Small World Problem,  Psychology Today,  2: 60-67 (1967).

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line-half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="vary-rewiring-probability" repetitions="20" runMetricsEveryTick="false">
    <setup>setup</setup>
    <go>spread-change</go>
    <exitCondition>not (any? nodes with [has-change? = false]) </exitCondition>
    <metric>clustering-coefficient</metric>
    <metric>time</metric>
    <enumeratedValueSet variable="rewiring-probability">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="num-nodes">
      <value value="40"/>
      <value value="100"/>
      <value value="150"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@